//htmlClient 客户端
import string.html;
import web.rest.client;
namespace web.rest; 

class htmlClient{
	ctor( ... ){
		this = ..web.rest.client( ... );
		 
		this.parseResponseResult = function(s){
			var t = this._http.responseContentType;
			if( t &&  ..string.match( t,"[\w\/]*<@@xml@>![\W]"  ) )
				return  ..string.html( s );
				
			s = ..string.trim(s);
			if( s[1] == '<'# ){
				return  ..string.html( s );
			}
			return;
		}
		this.acceptType = "application/xml,text/xml,*/*";
	}; 
}
 
/**intellisense()
web.rest.htmlClient = REST客户端\n普通表单请求,返回数据为string.html文档对象
web.rest.htmlClient() = 创建REST客户端,\n!web_restClient.
end intellisense**/