CFQUERY |
Description Passes queries or SQL statements to a data source. Macromedia recommends that you use the cfqueryparam tag within every cfquery tag, to help secure your databases from unauthorized users. For more information, see Security Bulletin ASB99-04, "Multiple SQL Statements in Dynamic Queries," in the Macromedia Security Zone, www.macromedia.com/devnet/security/security_zone/asb99-04.html, and Chapter 20, "Accessing and Retrieving Data" in ColdFusion MX Developer's Guide.
Category Database manipulation tags
Syntax
    <cfquery
       name = "query_name"
       dataSource = "ds_name"
       dbtype = "query"
       username = "username"
       password = "password"
       maxRows = "number"
       blockFactor = "blocksize"
       timeout = "seconds"
       cachedAfter = "date"
       cachedWithin = "timespan"

       Either of the following:
          debug = "yes" or "no"
       or:
          debug
    >
    result = "result_name"
    </cfquery>
See also cfinsert, cfprocparam, cfprocresult, cfqueryparam, cfstoredproc, cftransaction, cfupdate; "Optimizing database use" in Chapter 13, "Designing and Optimizing a ColdFusion Application," and Chapters 19-22 in ColdFusion MX Developer's Guide
History ColdFusion MX 7: Added the result attribute for specifying an alternate name for the structure that holds the result variables. Added result variables for the SQL statement executed (sql), the number of records returned (recordcount), whether the query was cached (cached), an array of cfqueryparam values (sqlparameters), and the list of columns in the returned query (columnlist). ColdFusion MX: Changed Query of Queries behavior: it now supports a larger subset of standard SQL. Changed dot notation support: ColdFusion now supports dot notation within a record set name. ColdFusion interprets such a name as a structure. Deprecated the connectString, dbName, dbServer, provider, providerDSN, and sql attributes, and all values of the dbtype attribute except query. They do not work, and might cause an error, in releases later than ColdFusion 5. New query object variable: cfquery.ExecutionTime. No longer supports native drivers. It now uses JDBC (and ODBC-JDBC bridge) for database connectivity.
Usage Use this tag to execute a SQL statement against a ColdFusion data source. Although you can use the cfquery tag to execute any SQL Data Definition Language (DDL) or Data Manipulation Language (DML) statement, you typically use it to execute a SQL SELECT statement.
Note: | To call a stored procedure, use the cfstoredproc tag.
This tag creates a query object, providing this information in query variables:
    query_name.currentRow
| Current row of query that cfoutput is processing.
    query_name.columnList
| Comma-delimited list of the query columns.
    query_name.RecordCount
| Number of records (rows) returned from the query.
The cfquery tag also returns the following result variables in a structure. You can access these variables with a prefix of the name you specified in the result attribute. For example, if you assign the name myResult to the result attribute, you would retrieve the name of the SQL statement that was executed by accessing #myResult.sql#. The result attribute provides a way for functions or CFCs that are called from multiple pages, possibly at the same time, to avoid overwriting results of one call with another.
    result_name.sql
| The SQL statement that was executed.
    result_name.recordcount
| Current row of query that cfoutput is processing.
    result_name.cached
| True if the query was cached; False otherwise.
    result_name.sqlparameters
| An ordered Array of cfqueryparam values.
    result_name.columnList
| Comma-delimited list of the query columns.
    result_name.ExecutionTime
| Cumulative time required to process the query.
You can cache query results and execute stored procedures. For information about this and about displaying cfquery output, see ColdFusion MX Developer's Guide. Because the timeout attribute only affects the maximum time for each suboperation of a query, the cumulative time may exceed its value. To set a timeout for a page that might get a very large result set, set the Administrator > Server Settings > Timeout Requests option to an appropriate value or use the RequestTimeout attribute of the cfsetting tag (for example, <cfsetting requestTimeout="300">). The Caching page of the ColdFusion MX Administrator specifies the maximum number of cached queries. Setting this value to 0 disables query caching. You cannot use ColdFusion reserved words as query names. You cannot use SQL reserved words as variable or column names in a Query of Queries, unless they are escaped. The escape character is the bracket []; for example:
    SELECT [count] FROM MYTABLE.
For a list of reserved keywords in ColdFusion MX, see "Escaping reserved keywords" in Chapter 22, "Using Query of Queries" in ColdFusion MX Developer's Guide.
Example
    <!--- This example shows the use of CreateTimeSpan with CFQUERY ------>
    <!--- to cache a record set. Define startrow and maxrows to ---->
    <!--- facilitate 'next N' style browsing. ---->
    <cfparam name="MaxRows" default="10">
    <cfparam name="StartRow" default="1">
    <!--------------------------------------------------------------------
    Query database for information if cached database information has
    not been updated in the last six hours; otherwise, use cached data.
    --------------------------------------------------------------------->
    <cfquery
    name="GetParks" datasource="cfdocexamples"
    cachedwithin="#CreateTimeSpan(0, 6, 0, 0)#">
    SELECT PARKNAME, REGION, STATE
    FROM Parks
    ORDER BY ParkName, State
    </cfquery>
    <!--- Build HTML table to display query. ------------------------->
    <table cellpadding="1" cellspacing="1">
       <tr>
          <td bgcolor="f0f0f0">
             &nbsp;
          </td>
          <td bgcolor="f0f0f0">
             <b><i>Park Name</i></b>
          </td>
          <td bgcolor="f0f0f0">
             <b><i>Region</i></b>
          </td>
          <td bgcolor="f0f0f0">
             <b><i>State</i></b>
          </td>
       </tr>
    <!--- Output the query and define the startrow and maxrows parameters.
    Use the query variable CurrentCount to keep track of the row you
    are displaying. ------>
    <cfoutput query="GetParks" startrow="#StartRow#" maxrows="#MaxRows#">
       <tr>
          <td valign="top" bgcolor="ffffed">
             <b>#GetParks.CurrentRow#</b>
          </td>
          <td valign="top">
             <font size="-1">#ParkName#</font>
          </td>
          <td valign="top">
             <font size="-1">#Region#</font>
          </td>
          <td valign="top">
             <font size="-1">#State#</font>
          </td>
       </tr>
    </cfoutput>
    <!--- If the total number of records is less than or equal
    to the total number of rows, then offer a link to
    the same page, with the startrow value incremented by
    maxrows (in the case of this example, incremented by 10). --------->
       <tr>
          <td colspan="4">
          <cfif (StartRow + MaxRows) LTE GetParks.RecordCount>
             <cfoutput><a href="#CGI.SCRIPT_NAME#?startrow=#Evaluate(StartRow +
    MaxRows)#">
             See next #MaxRows# rows</a></cfoutput>
          </cfif>
          </td>
       </tr>
    </table>

NAME |
| Required
Name of query. Used in page to reference query record set. Must begin with a letter. Can include letters, numbers, and underscores.

DATASOURCE |
| Required unless dbtype=query.
Name of data source from which query gets data. You must specify either dbtype or dataSource.

DBTYPE |
| Optional
Use this value to specify the results of a query as input. You must specify either dbtype or dataSource.

USERNAME |
| Optional
Overrides username in data source setup.

PASSWORD |
| Optional
Overrides password in data source setup.

MAXROWS |
| Optional
Default value: "-1 (All)" Maximum number of rows to return in record set.

BLOCKFACTOR |
| Optional
Default value: "1" Maximum rows to get at a time from server. Range: 1 - 100. Might not be supported by some database systems.

TIMEOUT |
Maximum number of seconds that each action of a query is permitted to execute before returning an error. The cumulative time may exceed this value. For JDBC statements, ColdFusion sets this attribute. For other drivers, check driver documentation.

CACHEDAFTER |
| Optional
Date value (for example, April 16, 1999, 4-16-99). If date of original query is after this date, ColdFusion uses cached query data. To use cached data, current query must use same SQL statement, data source, query name, user name, password. A date/time object is in the range 100 AD-9999 AD. When specifying a date value as a string, you must enclose it in quotation marks.

CACHEDWITHIN |
| Optional
Timespan, using the CreateTimeSpan function. If original query date falls within the time span, cached query data is used. CreateTimeSpan defines a period from the present, back. Takes effect only if query caching is enabled in the Administrator. To use cached data, the current query must use the same SQL statement, data source, query name, user name, and password.

DEBUG |
| Optional; value and equals sign may be omitted
Yes, or if omitted: if debugging is enabled, but the Administrator Database Activity option is not enabled, displays SQL submitted to datasource and number of records returned by query. No: if the Administrator Database Activity option is enabled, suppresses display.

RESULT |
| Optional
Specifies a name for the structure in which cfquery returns the result variables. For more information, see the Usage section .