
#在【记事本】中使用 input("...") 输出【99乘法表】
#\r\n 表示回车换行


#预处理函数: 可配置 MKScript 脚本加载后自动运行
#mkscript_config_auto_start()

#打开一个【记事本】
run("notepad", "", "", mkSW_SHOW)

#暂停一下: 因为打开【记事本】需要一点时间
sleep(500)


#查找【记事本】窗口
int hWindow = window_find("", "无标题 - 记事本")
 
if hWindow > 0
 
    #找到【记事本】窗口
  
    #如果窗口当前最小化了
    if window_is_iconic(hWindow) == mkTrue
    
        #恢复窗口显示
        window_show(hWindow, mkSW_RESTORE)
    
    endif
 
    #激活窗口
    window_set_active(hWindow)
    
    #暂停 0.5 秒
    sleep(500)
    
else
 
    #没找到【记事本】窗口
 
    #弹出信息提示对话框
    alert("在点【确定】按钮前，先新建一个空白的【文本文档】并打开。\r\n\r\n在点【确定】按钮后的 3 秒内，将焦点移到空白的【记事本】中。")
    
    #暂停 3 秒
    sleep(3000)
 
endif




#定义变量
int m
int n

#循环
for m = 1 to 9
    
    for n = 1 to m
    
        input(n + "x" + m + "=" + n * m + " ")        
        
        #暂停 100 毫秒
        sleep(100)
        
    next   
    
    #换行    
    input("\r\n")
    
next

input("\r\n\r\n完成\r\n")


#在【信息】框中显示
print("99乘法表完成了？")


#响铃 3 声
play_alert_sound(3)
