execute @e[tag=Murder] ~ ~ ~ scoreboard players tag @e[r=2,tag=Innocent,c=1] add FreezedInit
scoreboard players tag @e[tag=FreezedInit,c=1] add Init {OnGround:1b}

scoreboard players tag @e[tag=Init] remove FreezedInit
scoreboard players tag @e[tag=Init] remove Innocent

execute @e[tag=Init,c=1] ~ ~ ~ tellraw @a[tag=InGame] ["",{"text":"Freezun","color":"aqua","bold":"true"},{"text":" » ","color":"dark_gray"},{"selector":"@e[tag=Init]","bold":false,"color":"dark_aqua"},{"text":" ","color":"dark_gray"},{"text":"has been frozen!","color":"aqua"}]
execute @e[tag=Init] ~ ~ ~ summon area_effect_cloud ~ ~1.7 ~ {CustomName:"✻ §b§lFrozen§r ✻",CustomNameVisible:1b,Duration:600,Tags:["KillFreezed"]}
execute @e[tag=Init] ~ ~ ~ summon area_effect_cloud ~ ~ ~ {CustomName:"Pos",Duration:600}
execute @e[tag=Init] ~ ~ ~ summon area_effect_cloud ~ ~-5 ~ {CustomName:"IcePlacer",Duration:600,Tags:["SpawnedIcePlacer"]}

scoreboard players set @e[tag=Init] IceNumber 0
execute @e[tag=Init] ~ ~ ~ scoreboard players operation @s IceNumber > @e[tag=Freezed] IceNumber
scoreboard players add @e[tag=Init] IceNumber 1
scoreboard players operation @e[tag=SpawnedIcePlacer,type=area_effect_cloud] IceNumber = @e[tag=Init] IceNumber

scoreboard players tag @e[type=area_effect_cloud,name=IcePlacer,tag=SpawnedIcePlacer] remove SpawnedIcePlacer

entitydata @e[tag=Init,type=villager] {NoAI:1b}

scoreboard players set @e[tag=Init] TimeUntilDeath 30
scoreboard players set @e[tag=Init] Resurrecting 0

scoreboard players tag @a[tag=Init] remove StopFocusing
scoreboard players reset @a[tag=Init] FocusedSince
scoreboard players reset @a[tag=Init] NotFocusedSince

scoreboard teams join MurderAI @e[tag=Init]
scoreboard players tag @e[tag=Init] add Freezed
function main:scoreboard/game if @e[tag=Init]
scoreboard players tag @e[tag=Init] remove Init