# Deepener - eyes open 2 
# ===============================================================================
#
#
# Description:	This is part of a modular approach to hypnotic script assembly.
#		This script uses the standard eyes open and closed to bring about
#		deepening.  It has been enhanced with randomness in time and
#		in repetitions.  It also incorporates random other deepener files.
#
#
# Created by:
#			bi4u2bn
#
# Modifications:
# 			followthewatch55
#			Interstel@tampabayadult.net
#
# Revision History:
#			1.0	02/17/2005
#			1.3	05/09/2005
#			1.5	06/09/2005
#			2.0	08/04/2005
#
# Variables Used:
#			name:		default VH name of subject
#			100:		random numbers to get total time passage
#			103:		temp name holder assign from %103% or %254%
#			104:		random variable
#			105:		counter
#			106:		random variable
#			107:		random variable
#			120:		is the passing variable for passing the time variable
#			121:		is storage var for 1st interval time passing
#			122:		is storage var for 2nd interval time passing
#			123:		is storage var for 3rd interval time passing
#			130:		is storage var for 1st interval for repetition passing
#			131:		is storage var for 2nd interval for repetition passing
#			249:		if "y" present use slave name
#			254:		slave name of subject
#
# Comments:
#			This module makes use of random pause intervals
#			so that complacency and/or defenses can be side
#			stepped.  %100% is an internal sentence pause.
#			While %101% is a longer end of sentence pause.
#			5 variables are passed to this script which are
#			%121%, %122%, %123%, %130% and %131%
#
#
# Begin:
#	Test to see if slave name
#
<set 103> %name%
<if 249=> y
<set 103> %254%
#
# setup
#
<calc 121*> 1000
<calc 122*> 1000
<calc 123*> 1000
#
# opening setting conditions
#
<speak> When I say   \pau=1000\   \emp\1   \pau=500\   \emp\2   \pau=500\   \emp\3   \pau=500\   eyes open   \pau=1000\   you will open your eyes   \pau=3000\
<speak> When you open your eyes   \pau=1000\   you will remain in trance and respond to my voice.   \pau=1000\
<speak> The moment you hear me say after that   \pau=1000\   \emp\deep \emp\asleep   \pau=1000\   your eyes will close.   \pau=1000\
<speak> And your body will go right back into this deeply relaxed state sinking deeper and deeper.   \pau=1000\
<speak> From now on whenever you hear someone say   \pau=1000\   \emp\deep \emp\asleep   \pau=1000\   you will return to this deeply relaxed state.   \pau=1000\
<speak> Every time you hear   \pau=1000\   \emp\deep \emp\asleep   \pau=1000\   you will go deeper and deeper into this sweet trance.   \pau=1000\
#
# Set 1 to Nth Random Repetitions
# based on %130% variable
# 
<set 104> 0
<set 105> 0
<calc %130%*> 3
<rand 3,%130%> 104
#
# begin loop outer
#
LOOPOUTER:
<calc 105+> 1
<if 105>> %104%
<gotolabel> EXIT
<rand 500,%121%> 120
<speak> \pau=%120%\
#
# awaken to trance eyes open
#
<speak> 1... \pau=500\
<speak> 2... \pau=500\
<speak> 3... \pau=500\
<speak> Eyes open...
#
# Set 1 to Nth Random Repetitions
# based on %131% variable keyword repetitions
#
<Set 106> 0
<set 107> 0
<rand 1,%131%> 106
#
# begin loop inner
#
LOOPINNER:
<calc 107+> 1
<if 107>> %106%
<gotolabel> ENDLOOPINNER
<rand 500,%122%> 120
<speak> \pau=%120%\
#
# send back asleep
#
<speak> \emp\deep \emp\asleep
<rand 500,%123%> 120
<speak> \pau=%120%\
#
# end loop inner
#
<gotolabel> LOOPINNER
ENDLOOPINNER:
#
# end outer loop
#
<gotolabel> LOOPOUTER
#
# End:
#
EXIT:
<end>
