#Featuretest script
#by FollowTheWatch55

<set 9> 2000

<speak> Hello %name%, this is a Virtual Hypnotist feature test.

<yesno> Do you like this program?
<set 1> %yesno%

<keybuffer>
<speak> Press any key. \Pau=4000\
<getkey>
<set 2> %key%

<gettext>
<set 3> %text%

<speak> The inputs were %1% %2% and %3%

<yesno> Do you want to test the speech recognition?
<if> %yesno% = no
<gotolabel> calctest
<voicebuffer>
<speak> Say something
<getvoice>
<set 4> %voice%
<speak> You said %4%

inputtest:
<voicebuffer>
<speak> Say the word Sleep
<getvoice>
<if> %voice% = sleep
   <gotolabel> calctest
   <gotolabel> inputtest

calctest:
<speak> What is 21 divided by 5?
<speak> It is (21 / 5)

<speak> I'll pick a number from 1 to 10 and you can try guessing it.
<set 6> (1 @ 10)
<pause> 5000
<speak> Give up? The number is %6%

<speak> Enough with the boring stuff. Now for the special effects.

effect1:
<set 7> (1 @ 30)
<set 8> (1 @ 2)
<if> %8% = 1
   <charh> -%7%
   <charh> %7%

<set 7> (1 @ %9%)
<pause> %7%

<gotolabel> loop

effect2:
<set 7> (1 @ 30)
<set 8> (1 @ 2)
<if> %8% = 1
   <charv> -%7%
   <charv> %7%

<set 7> (1 @ %9%)
<pause> %7%

<gotolabel> loop

effect3:
<set 7> (70 @ 160)
<charzoom> %7%

<set 7> (1 @ %9%)
<pause> %7%

<gotolabel> loop

effect4:
<set 7> (70 @ 160)
<vidzoom> %7%

<set 7> (1 @ %9%)
<pause> %7%

<gotolabel> loop

effect5:
<set 7> (70 @ 160)
<vidrate> %7%

<set 7> (1 @ %9%)
<pause> %7%

<gotolabel> loop

effect6:
<set 7> (1 @ 2)
<if> %7% = 1
   <sound> snap.wav
   <sound> hypno.wma

<set 7> (1 @ %9%)
<pause> %7%

<gotolabel> loop
 
effect7:
<set 7> (1 @ 200)
<backrate> %7%

<set 7> (1 @ %9%)
<pause> %7%

loop:
<set 9> (%9% - 10)
<if> %9% < 1
   <end>
<set 7> (1 @ 7)
<if> %7% = 1
   <gotolabel> effect1
<if> %7% = 2
   <gotolabel> effect2
<if> %7% = 3
   <gotolabel> effect3
<if> %7% = 4
   <gotolabel> effect4
<if> %7% = 5
   <gotolabel> effect5
<if> %7% = 6
   <gotolabel> effect6
<if> %7% = 7
   <gotolabel> effect7
