儿童睡前故事电脑版 v1.5下载

儿童睡前故事电脑版软件

儿童睡前故事电脑版是非常多的人都在使用人用的一款少儿睡前故事大全软件，能够语音讲故事更容易被接受，更让宝宝觉得有一种安全感，让宝宝知道宝宝即使在睡觉的时候也有爸爸妈妈的陪伴和保护。接下来非凡软件站小编就给大家带来这款软件的具体介绍，感兴趣的小伙伴们速来看看吧~~

儿童睡前故事电脑版是非常多的人都在使用人用的一款少儿睡前故事大全软件，能够语音讲故事更容易被接受，更让宝宝觉得有一种安全感，让宝宝知道宝宝即使在睡觉的时候也有爸爸妈妈的陪伴和保护。接下来非凡软件站小编就给大家带来这款软件的具体介绍，感兴趣的小伙伴们速来看看吧~~

使用说明：

软件用的是微软自带的语音包，在软件压缩包当中附带得有。在网上查阅过，都说XP以后都已经支持了，但是不知道你们用的系统是否被删除过相关的语音包，所以附带了微软的。

如何确定自己是否已经安装过语音包？

暂停键旁边有一个下拉框，如果下拉框是空的，那么就说明你没有安装过，需要安装后才能显示，同时软件也会检测并提醒！

由于之前发表一次说我没有相关原创的信息，这次补上！下面是开发截图和版权截图，如果还不够，那么我只剩下开源这样才行了！反正这个软件也不是什么很难写的东西，开源也行！如果大家喜欢的话！

开发截图

备注：如果大家有更好的想法或语音API，请私信我！或者回帖交流！最后我也不知道过不过审核，干脆直接把源代码贴出来吧！

.版本 2

.支持库 RegEx

.支持库 ESpeechEngine

.支持库 internet

.支持库 iext

.程序集 窗口程序集_启动窗口

.程序集变量 Json, 类_json

.程序集变量 zz, 正则表达式

.程序集变量 搜索, 搜索结果, , "0"

.程序集变量 jd, 机读文本

.程序集变量 d, 文本型, , "0"

.程序集变量 zt, 标签

.子程序 __启动窗口_创建完毕

页数 ＝ “1”

读取数据 (页数)

初始化朗诵 ()

置托盘图标 (#图标, “睡前故事”)

.子程序 读取数据

.参数 页数, 文本型

.局部变量 返回数据, 文本型

.局部变量 临时变量, 文本型

临时变量 ＝ 子文本替换 (#POST数据, “【页数】”, 页数, , , 真)

返回数据 ＝ 到文本 (HTTP读文件 (临时变量))

返回数据 ＝ 子文本替换 (返回数据, “⁄/”, “/”, , , 真)

处理数据 (返回数据)

.子程序 下一页

.参数 传递页数, 文本型

页数 ＝ 到文本 (到整数 (传递页数) ＋ 10)

.子程序 处理数据

.参数 传输数据, 文本型

.局部变量 title, 文本型, , "0"

.局部变量 img, 文本型, , "0"

.局部变量 url, 文本型, , "0"

.局部变量 description, 文本型, , "0"

.局部变量 i, 整数型

.局部变量 索引, 整数型

Json.解析 (传输数据)

.计次循环首 (Json.成员数 (), i)

加入成员 (title, Json.取通用属性 (“[” ＋ 到文本 (i － 1) ＋ “].title”))

加入成员 (img, Json.取通用属性 (“[” ＋ 到文本 (i － 1) ＋ “].img”))

加入成员 (url, Json.取通用属性 (“[” ＋ 到文本 (i － 1) ＋ “].url”))

加入成员 (description, Json.取通用属性 (“[” ＋ 到文本 (i － 1) ＋ “].description”))

索引 ＝ 超级列表框1.插入表项 (, , , , , )

超级列表框1.置标题 (索引, 0, 到文本 (索引 ＋ 1))

超级列表框1.置标题 (索引, 1, title [i])

超级列表框1.置标题 (索引, 2, description [i])

超级列表框1.置标题 (索引, 3, img [i])

超级列表框1.置标题 (索引, 4, url [i])

.计次循环尾 ()

.子程序 _超级列表框1_被双击, 逻辑型

.参数 横向位置, 整数型

.参数 纵向位置, 整数型

.参数 功能键状态, 整数型

.如果 (超级列表框1.现行选中项 ≠ -1)

标签2.标题 ＝ “《” ＋ 超级列表框1.取标题 (超级列表框1.现行选中项, 1) ＋ “》”

标签4.标题 ＝ “ ” ＋ 超级列表框1.取标题 (超级列表框1.现行选中项, 2)

图片框1.图片 ＝ HTTP读文件 (超级列表框1.取标题 (超级列表框1.现行选中项, 3))

获取故事 (超级列表框1.取标题 (超级列表框1.现行选中项, 4))

.否则

信息框 (“无法获取数据”, 0, “请检查网络通信是否正常？”, )

.如果结束

.子程序 获取故事

.参数 url, 文本型

.局部变量 临时数据, 文本型

.局部变量 i, 整数型

临时数据 ＝ 编码_utf8到gb2312 (到文本 (HTTP读文件 (url)))

zz.创建 (#正则方法, )

搜索 ＝ zz.搜索全部 (临时数据)

.判断开始 (取数组成员数 (搜索) ＞ 0)

编辑框1.内容 ＝ 网页_取文本_dom (搜索 [1].取匹配文本 (临时数据, ))

.默认

.判断结束

.子程序 _滑块条2_位置被改变

滑块条2.选择长度 ＝ 滑块条2.位置

标签3.标题 ＝ “音量：” ＋ 到文本 (滑块条2.位置)

jd.设置声音大小 (滑块条2.位置)

.子程序 _滑块条1_位置被改变

标签1.标题 ＝ “语速：” ＋ 到文本 (滑块条1.位置)

jd.设置语速 (滑块条1.位置)

.子程序 _超级列表框1_右键单击表项

弹出菜单 (功能, , )

.子程序 _获取新数据_被选择

下一页 (页数)

读取数据 (页数)

.子程序 初始化朗诵

.局部变量 i, 整数型

d ＝ jd.列举语音库 ()

.如果 (取数组成员数 (d) ＞ 0)

组合框1.刷新显示 ()

.计次循环首 (取数组成员数 (d), i)

组合框1.插入项目 (i － 1, d [i], )

.计次循环尾 ()

组合框1.现行选中项 ＝ 0

jd.设置语音库 (组合框1.被选择文本)

jd.设置语速 (滑块条1.位置)

jd.设置声音大小 (滑块条2.位置)

.否则

信息框 (“请先安装压缩包中的语言包”, 0, “语言包未安装”, )

.如果结束

.子程序 _按钮2_被单击

.如果 (按钮2.标题 ＝ “朗诵”)

按钮2.标题 ＝ “关闭”

.如果真 (编辑框1.内容 ≠ “”)

jd.文本到语音 (0, 编辑框1.内容, , )

.如果真结束

.否则

按钮2.标题 ＝ “朗诵”

jd.停止发音 ()

.如果结束

.子程序 _按钮3_被单击

.如果 (按钮3.标题 ＝ “暂停”)

按钮3.标题 ＝ “恢复”

jd.暂停发音 ()

.否则

按钮3.标题 ＝ “暂停”

jd.恢复发音 ()

.如果结束

.子程序 _超级列表框1_按下某键, 逻辑型

.参数 键代码, 整数型

.参数 功能键状态, 整数型

.如果真 (键代码 ＝ #F5键)

_获取新数据_被选择 ()

.如果真结束

.子程序 _版权所有_被选择

信息框 (“软件免费试用 版权所有 Mr.Liu ” ＋ #换行符 ＋ #换行符 ＋ “52 作者：djlyr”, 0, “版权信息”, )

.子程序 __启动窗口_托盘事件

.参数 操作类型, 整数型

.如果真 (操作类型 ＝ #单击右键)

弹出菜单 (版权, , )

.如果真结束

.版本 2

.全局变量 页数, 文本型

.版本 2

.常量 POST数据, "<文本长度: 94="">"

具体内容：https://dynamic.qbaobei.com/dynamic.php?s=/qbaobeimobile/cate_position/cate/1414/star/【页数】

.常量 正则方法, "<文本长度: 36="">"

具体内容：

([⁄s⁄S]*?)

以上就是儿童睡前故事电脑版的全部内容了，快快收藏非凡软件站下载更多软件和游戏吧！

下载帮助：点击儿童睡前故事电脑版软件立即下载，解压后安装，一直点下一步，直到安装完成，再打开使用。